flake-iter/flake.nix at main · DeterminateSystems/flake-iter · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
# This flake was initially generated by fh, the CLI for FlakeHub (version 0.1.10)
{
  description = "flake-iter";

  inputs = {
    nixpkgs.url = "https://flakehub.com/f/NixOS/nixpkgs/0";
    fenix = {
      url = "https://flakehub.com/f/nix-community/fenix/0.1.1885";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    crane = {
      url = "https://flakehub.com/f/ipetkov/crane/0.20";
    };
    flake-schemas.url = "https://flakehub.com/f/DeterminateSystems/flake-schemas/0.3";
  };

  outputs =
    { self, ... }@inputs:
    let
      inherit (inputs.nixpkgs) lib;

      supportedSystems = [
        "x86_64-linux"
        "aarch64-darwin"
        "aarch64-linux"
      ];

      forEachSupportedSystem =
        f:
        lib.genAttrs supportedSystems (
          system:
          f {
            inherit system;
            pkgs = import inputs.nixpkgs {
              inherit system;
              overlays = [ self.overlays.default ];
            };
          }
        );
      meta = (builtins.fromTOML (builtins.readFile ./Cargo.toml)).package;
    in
    {
      inherit (inputs.flake-schemas) schemas;

      overlays.default = final: prev: rec {
        system = final.stdenv.hostPlatform.system;
        rustToolchain =
          with inputs.fenix.packages.${system};
          combine (
            [
              stable.clippy
              stable.rustc
              stable.cargo
              stable.rustfmt
              stable.rust-src
            ]
            ++ lib.optionals (system == "x86_64-linux") [
              targets.x86_64-unknown-linux-musl.stable.rust-std
            ]
            ++ lib.optionals (system == "aarch64-linux") [
              targets.aarch64-unknown-linux-musl.stable.rust-std
            ]
          );
        craneLib = (inputs.crane.mkLib final).overrideToolchain rustToolchain;
      };

      devShells = forEachSupportedSystem (
        { pkgs, system }:
        rec {
          default = pkgs.mkShell {
            packages = with pkgs; [
              rustToolchain
              cargo-edit
              cargo-watch
              bacon
              rust-analyzer
              cargo-machete
              iconv
              self.formatter.${system}
            ];

            env = {
              RUST_SRC_PATH = "${pkgs.rustToolchain}/lib/rustlib/src/rust/library";
            };
          };

          a = default;
          b = default;
          c = default;
          d = default;
        }
      );

      formatter = forEachSupportedSystem ({ pkgs, ... }: pkgs.nixfmt);

      # These outputs are solely for local testing
      packages = forEachSupportedSystem (
        { pkgs, ... }:
        rec {
          default = pkgs.craneLib.buildPackage {
            pname = meta.name;
            inherit (meta) version;
            src = self;
            doCheck = true;
            buildInputs = with pkgs; [ iconv ];
          };

          a = default;
          b = default;
          c = default;
          d = pkgs.jq;
          e = pkgs.ponysay;
          f = pkgs.hello;
        }
      );
    };
}