libplanes/CMakeLists.txt at master · linux4sam/libplanes · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
cmake_minimum_required(VERSION 3.23)

project(libplanes
    VERSION 2.0.1
    DESCRIPTION "Microchip hardware LCD plane library"
    LANGUAGES C
)
#set(PROJECT_VERSION_RC 1)
if(DEFINED PROJECT_VERSION_RC)
    string(APPEND PROJECT_VERSION "-rc${PROJECT_VERSION_RC}")
endif()

include(GNUInstallDirs)

set(CMAKE_VERBOSE_MAKEFILE True)

add_compile_options(-Wall -Wextra)
add_compile_options(-Wsign-compare)
add_compile_options(-Werror-implicit-function-declaration)
add_compile_options(-Wpointer-arith)
add_compile_options(-Wwrite-strings)
add_compile_options(-Wstrict-prototypes)
add_compile_options(-Wmissing-prototypes -Wmissing-declarations)
add_compile_options(-Wnested-externs)
add_compile_options(-Wpacked)
add_compile_options(-Wswitch-enum)
add_compile_options(-Wstrict-aliasing=2)
add_compile_options(-Winit-self)
add_compile_options(-Wdeclaration-after-statement)
add_compile_options(-Wold-style-definition)
add_compile_options(-Wno-unused-parameter)
add_compile_options(-Wno-attributes)
add_compile_options(-Wno-long-long)
add_compile_options(-Winline)
add_compile_options(-Wshadow)
add_compile_options(-Wno-missing-field-initializers)

option(BUILD_SHARED_LIBS "Build using shared libraries" ON)

find_package(PkgConfig REQUIRED)

pkg_check_modules(LIBDRM REQUIRED libdrm>=2.4.0)
set(AX_PACKAGE_REQUIRES "libdrm >= 2.4.0")

pkg_check_modules(DIRECTFB directfb>=1.7.0)

option(ENABLE_ENGINE "enable/disable engine [default=OFF]" OFF)
if(ENABLE_ENGINE)
    pkg_check_modules(CAIRO REQUIRED cairo>=1.14.6)
    set(AX_PACKAGE_REQUIRES_PRIVATE "cairo >= 1.14.6")

    pkg_check_modules(CJSON REQUIRED libcjson>=1.6.0)
    set(AX_PACKAGE_REQUIRES_PRIVATE "${AX_PACKAGE_REQUIRES_PRIVATE} libcjson >= 1.6.0")

    pkg_search_module(LUA REQUIRED lua>=5.3.1 lua5.3)
    set(AX_PACKAGE_REQUIRES_PRIVATE "${AX_PACKAGE_REQUIRES_PRIVATE} lua >= 5.3.1")

    find_package(Python3 COMPONENTS Interpreter Development)
    if(Python3_FOUND)
        find_package(SWIG REQUIRED COMPONENTS python)
    endif()
endif()

add_subdirectory(src)

if(ENABLE_ENGINE OR DIRECTFB_FOUND)
    add_subdirectory(apps)
endif()

if(Python3_FOUND AND SWIG_FOUND)
    add_subdirectory(python)
endif()

find_package(Doxygen COMPONENTS doxygen)
if(Doxygen_FOUND)
    set(DOXYGEN_FILE_PATTERNS *.c *.h *.md)
    set(DOXYGEN_PROJECT_LOGO "${PROJECT_SOURCE_DIR}/docs/logo55.png")
    set(DOXYGEN_USE_MDFILE_AS_MAINPAGE "${PROJECT_SOURCE_DIR}/README.md")
    set(DOXYGEN_OUTPUT_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/docs")
    doxygen_add_docs(docs ${PROJECT_SOURCE_DIR})
endif()