justfile

# The example components and host runners: one guest component, every
# host. The conformance suite is the behavioral gate; these show the
# surface in use.

import '../justfile.shared.just'

default: test

# Build the echo-demo guest into target/components/echo-demo.wasm.
component: (build-component "echo-demo")

# The wasmtime demo, end to end (used by CI).
test: component build-echod
    cargo test -p wasmtime-demo

# Run the native demo by hand: `just demo::wasmtime [count]`.
wasmtime count="100": component build-echod
    cargo run -p wasmtime-demo -- {{root}}/target/components/echo-demo.wasm {{count}}

# Run the JS-host demo by hand: `just demo::polyengine [count]` — the same
# component runtime-linked under polyengine on stock Deno against
# js/polyengine/websocket.ts, with no transpile step and no engine flag. The
# translator comes from the packaged `@polyengine/translator` JSR prerelease
# through the module graph — no fetch step. The polyengine pin is single-site:
# the import map is conformance/driver-ct/polyengine/deno.json.
polyengine count="100": component build-echod
    #!/usr/bin/env bash
    set -euo pipefail
    # --allow-run is unscoped for the same reason run-polyengine's is: Deno
    # refuses a scoped --allow-run whenever dynamic-linker vars sit in the
    # ambient environment (see the conformance-ct::run-polyengine comment).
    deno run \
        --config {{root}}/conformance/driver-ct/polyengine/deno.json --frozen \
        --allow-read={{root}} \
        --allow-net=127.0.0.1,localhost \
        --allow-run \
        {{root}}/examples/polyengine-demo/run.ts {{count}}

[private]
build-echod:
    cargo build -p conformance-echod